Công thức đếm cơ bản

Ta lần lượt thực hiện các công thức đếm sau : 1/ Đếm tổng số ô : Số ô có trong mảng dữ liệu Data A1:B10 là : =ROWSData*COLUMNSData 2/Đếm các ô trống : =COUNTBLANKData Hàm COUNTBLANK cũng

A/ Các công thức đếm cơ bản :

Ta có mảng dữ liệu A1:B10 có tên là Data Mảng này sẽ có những ô trống, những ô chứa giá trị Text, số, những ô lỗi #N/A, #DIV/0, #NAME?,

#NULL!, #VALUE!, #REF! Ta lần lượt thực hiện các công thức đếm sau :

1/ Đếm tổng số ô :

Số ô có trong mảng dữ liệu Data A1:B10 là :

=ROWS(Data)*COLUMNS(Data)

2/Đếm các ô trống :

=COUNTBLANK(Data)

Hàm COUNTBLANK cũng đếm các ô chứa một công thức vốn trả về một chuỗi rỗng TD : Công thức sau sẽ trả về một chuỗi rỗng nếu giá trị trong ô A1 lớn hơn 5 Nếu ô A1 đáp ứng điều kiện này, hàm COUNTBLANK sẽ đếm ô đó

=IF(A1>5,"",A1)

Bạn cũng có thể đếm số ô trống trong cột A bằng công thức sau :

=COUNTBLANK(A:A)

Và số ô trống trên tòan bộ Sheet1 :

=COUNTBLANK(Sheet1!1:65536)

Dĩ nhiên, bạn phải nhập công thức trên một Sheet khác ngọai trừ Sheet1, nếu không nó sẽ tạo ra tham chiếu vòng

Lưu ý : Hàm COUNTBLANK sẽ không đếm các ô chứa giá trị 0, ngay cả bạn hủy tùy chọn Zero Value trong Tools/Option

3/Đếm các ô không trống :

=COUNTA(Data)

Hàm COUNTA đếm các giá trị Text hoặc các giá trị Logic (TRUE hoặc FALSE) Nếu một ô chứa công thức trả kết quả về một chuỗi rỗng, hàm COUNTA cũng đếm luôn ô này

4/Đếm các ô số :

=COUNT(Data)

Các ô chứa giá trị logic (TRUE hay FALSE) không được xem là ô số Hàm COUNT cũng đếm các ô chứa giá trị thời gian hay ngày tháng

5/Đếm các ô không phải Text :

{=SUM(IF(ISNONTEXT(Data),1))}

6/Đếm các ô Text :

{=SUM(IF(ISTEXT(Data),1))}

7/Đếm các giá trị Logic :

{=SUM(IF(ISLOGIC(Data),1))}

Nếu muốn biết các công thức mảng trên họat động ra sao, các bạn có thể

tham khảo thêm ở bài "Mảng và công thức mảng".

8/Đếm các giá trị lỗi trong một dãy :

Excel có 3 hàm để giúp bạn quyết định xem ô có chứa giá trị lỗi hay không :

- ISERROR : Trả về TRUE nếu ô chứa bất kỳ giá trị lỗi (#N/A, #VALUE,

#REF!, #DIV/0!, #NUM!, #NAME?, hoặc #NULL!)

-ISERR : Trả về TRUE nếu ô chứa bất kỳ giá trị lỗi ngọai trừ #N/A

-ISNA : Trả về TRUE nếu ô chứa giá trị lỗi #N/A Bạn có thể sử dụng các hàm này trong công thức mảng để đếm giá trị lỗi trong một dãy, tùy nhu cầu của bạn

{=SUM(IF(ISERROR(Data),1))}

{=SUM(IF(ISERR(Data),1))}

{=SUM(IF(ISNA(Data),1))}

Nếu bạn muốn đếm cụ thể các lỗi, bạn có thể sử dụng hàm COUNTIF

=COUNTIF(Data,"#DIV/0!")